Internet Info 1993/Internet Info CD-ROM (Walnut Creek) (1993).iso/networking/terms/kermit/b/vmsins.com

Text File | 1991-04-30 | 3.2 KB | 107 lines

$!  Modified, J Klensin, [e-mail], 860927, to work with current
$!   Columbia naming scheme and to operate correctly when not rebuilding.
$ ON CONTROL_Y THEN GOTO DONE
$ SET PROT=(S:RWED,G:RWED,O:RWED,W:RE)/DEFAULT
$ SYSDISK = F$LOGICAL("SYS$DISK")
$ DEFUIC:='F$USER()
$ OLDPRIVS = ""
$ EXIT_MESSAGE = " Kermit-32 installation abnormally terminated."
$ SET NOON
$ WRITE SYS$OUTPUT " "
$ WRITE SYS$OUTPUT "                Kermit-32 Installation Procedure"
$ WRITE SYS$OUTPUT " "
$
$ LANG_TYPE = ""
$ INQUIRE DO_INSTALL " Rebuild from sources? (YES or NO) "
$ IF DO_INSTALL .EQS. "" THEN GOTO INS
$ IF .NOT. DO_INSTALL THEN GOTO INS
$
$LANG_QUESTION:
$ INQUIRE LANG_TYPE " Which version? (BLISS or MACRO) "
$ IF LANG_TYPE .EQS. "" THEN GOTO LANG_ERR
$ IF LANG_TYPE .EQS. "BLISS" .OR. LANG_TYPE .EQS. "bliss" THEN GOTO INS
$ IF LANG_TYPE .EQS. "MACRO" .OR. LANG_TYPE .EQS. "macro" THEN GOTO INS
$
$LANG_ERR:
$ WRITE SYS$OUTPUT " Respond with ""BLISS"" or ""MACRO"""
$ GOTO LANG_QUESTION
$
$INS:
$ INQUIRE DO_INS " Install Kermit-32 on the system?"
$
$ IF DO_INS .EQS. "" THEN GOTO INS
$ IF LANG_TYPE .EQS. "BLISS" .OR. LANG_TYPE .EQS. "bliss" THEN GOTO BLI
$ IF LANG_TYPE .EQS. "MACRO" .OR. LANG_TYPE .EQS. "macro" THEN GOTO MAR
$ GOTO BLDCOM
$
$BLI:
$ WRITE SYS$OUTPUT " This may take some time"
$ BLISS VMSMIT.BLI/OBJECT=KERMIT
$ BLISS VMSMSG.BLI/OBJECT=KERMSG
$ BLISS VMSGLB.BLI/OBJECT=KERGLB
$ BLISS VMSTRM.BLI/OBJECT=KERTRM
$ BLISS VMSFIL.BLI/OBJECT=KERFIL
$ BLISS VMSTT.BLI/OBJECT=KERTT
$ BLISS VMSSYS.BLI/OBJECT=KERSYS
$ MACRO VMSGEN.MAR/OBJECT=KERGEN.OBJ
$
$ GOTO LINK_AND_BLDCOM
$
$MAR:
$ WRITE SYS$OUTPUT " This may take some time"
$ MACRO VMSMIT.MAR/OBJECT=KERMIT
$ MACRO VMSMSG.MAR/OBJECT=KERMSG
$ MACRO VMSGLB.MAR/OBJECT=KERGLB
$ MACRO VMSTRM.MAR/OBJECT=KERTRM
$ MACRO VMSFIL.MAR/OBJECT=KERFIL
$ MACRO VMSTT.MAR/OBJECT=KERTT
$ MACRO VMSSYS.MAR/OBJECT=KERSYS
$ MACRO VMSGEN.MAR/OBJECT=KERGEN
$
$LINK_AND_BLDCOM:
$ MESSAGE VMSERR.MSG
$ LINK KERMIT, KERMSG, KERGLB, KERTRM, KERFIL, KERTT, VMSERR, KERSYS, KERGEN
$
$BLDCOM:
$
$ IF .NOT. DO_INS THEN GOTO SUCCESS
$
$ OLDPRIVS = F$SETPRV ("CMKRNL")
$ IF F$PRIVILEGE ("CMKRNL") THEN GOTO BLDC1
$   EXIT_MESSAGE = " Insufficient privilege to perform installation."
$   GOTO SUCCESS
$BLDC1:
$ SET UIC [001,004]
$ COPY/LOG KERMIT.EXE SYS$SYSTEM:KERMIT.EXE
$   inquire reinst_help " Reinstall help files?"
$   if .not. reinst_help then goto success
$ LIBRARY/LOG/HELP/DELETE=KERMIT SYS$HELP:HELPLIB.HLB
$ RUNOFF VMSMIT.RNH/VAR=SYSTEM/OUTPUT=KERMIT.HLP
$ LIBRARY/LOG/INSERT/HELP SYS$HELP:HELPLIB.HLB KERMIT.HLP
$ RUNOFF VMSMIT.RNH/OUTPUT=KERMIT.HLP
$ LIBRARY/LOG/CREATE/HELP SYS$HELP:KERMIT.HLB KERMIT.HLP
$
$SUCCESS:
$ EXIT_MESSAGE = " Kermit-32 installation is complete."
$
$   if lang_type .eqs. "" then goto skip_hexdehex
$ WRITE SYS$OUTPUT " VMSHEX and VMSDEH are the hexify/dehexify routines"
$ WRITE SYS$OUTPUT " for VMS Files-11 files. They are compiled and linked,"
$ WRITE SYS$OUTPUT " but not installed."
$ MACRO VMSDEH
$ MACRO VMSHEX
$ LINK VMSDEH
$ LINK VMSHEX
$skip_hexdehex:
$
$DONE:
$ ON CONTROL_Y THEN GOTO DONE3
$ SET NOON
$
$DONE3:
$ IF "''DEFUIC'" .NES. "" THEN SET UIC 'DEFUIC'
$ IF "''OLDPRIVS'" .NES. "" THEN XXPRIVS = F$SETPRV ("''OLDPRIVS'")
$ WRITE SYS$OUTPUT EXIT_MESSAGE
$ SET ON
$ EXIT